2011年5月29日日曜日

リモートマシンで共有ファイルを開かせる

このシステムのしくみ


サーバーにてExcSnd.vbsを実行すると、ExcSnd.vbsのプログラム上でリモートマシンに接続し、サーバー上のファイルを開かせる。
このサンプルでは、サーバー上にあるExcSnd.exeという音を出すファイルをリモートマシン上で実行させるためのVBScript。
サーバー上で実行するのは、Facade.vbs。
Facade.vbsより、メインのExcSnd.vbsを実行する。
Facade.vbsでは、他にもいくつかの共通モジュールを使用している。
それらの共通モジュールは、いかちソフトウェアのVBScriptサイトから入手できる。

ExcSnd.vbs
  1. Option Excplicit
  3. '==============================
  4. ' 定数定義
  5. '==============================
  6. 'サーバー名
  7. 'TODO:サーバー名を指定
  8. Const SERVER_NAME = "[サーバー名]"
  10. '共有フォルダ名
  11. '※ExcSnd.exeは、VBSモジュールと同一のフォルダに格納し、共有フォルダに設定
  12. Const SHARED_PATH = "TEST\source\ExcSnd\"
  14. '対象マシン一覧ファイル
  15. Const TARGET_MACHINE_FILE = ".\tgtfnlst.csv"
  17. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  18. ' 警告音を出すためのクラス
  19. '++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  20. Class ExcSnd
  21.     '==============================
  22.     ' 変数定義
  23.     '==============================
  24.     'メッセージ
  25.     Private mstrMessage
  27.     '==============================
  28.     ' プロパティ
  29.     '==============================
  30.     'メッセージ
  31.     Public Property Get Message()
  32.         Message = mstrMessage
  33.     End Property
  34.     Private Property Let Message(ByVal vstrMsg)
  35.         mstrMessage = vstrMsg
  36.     End Property
  38.     '********************************************************************************
  39.     ' メソッド名：PlaySound
  40.     ' 概要　　　：警告音を出す（Windows XP Exclamation.wav）
  41.     ' パラメータ：なし
  42.     ' 戻り値　　：正常実行ならTrue、そうでなければFalse
  43.     '********************************************************************************
  44.     Public Function PlaySound()
  45.         PlaySound = False
  47.         '対象マシンの一覧を読み込み
  48.         Dim varMachine
  49.         If ReadMachineList(varMachine) = False Then
  50.             Exit Function
  51.         End If
  53.         '対象マシンの警告音を出す
  54.         If UBound(varMachine) > 0 Then
  55.             If PlaySoundPersonal(varMachine) = False Then
  56.                 Exit Function
  57.             End If
  58.         End If
  60.         PlaySound = True
  61.     End Function
  63.     '********************************************************************************
  64.     ' メソッド名：ReadMachineList
  65.     ' 概要　　　：警告音を出す対象となるマシンの一覧を読み込む
  66.     ' パラメータ：[rvarMachine] - 対象マシン一覧
  67.     ' 戻り値　　：正常に読み込めたらTrue、そうでなければFalse
  68.     '********************************************************************************
  69.     Private Function ReadMachineList(ByRef rvarMachine)
  70.         ReadMachineList = False
  72.         Dim objTfm
  73.         Set objTfm = New TextFileManager
  75.         Dim strBuf
  76.         strBuf = objTfm.ReadText(TARGET_MACHINE_FILE)
  78.         rvarMachine = Split(strBuf, vbCrLf)
  80.         ReadMachineList = True
  81.     End Function
  83.     '********************************************************************************
  84.     ' メソッド名：PlaySoundPersonal
  85.     ' 概要　　　：マシン個別に警告音を出す
  86.     ' パラメータ：[rvarMachine] - 対象マシン一覧
  87.     ' 戻り値　　：正常に音声出力できたらTrue、そうでなければFalse
  88.     '********************************************************************************
  89.     Private Function PlaySoundPersonal(ByRef rvarMachine)
  90.         PlaySoundPersonal = False
  92.         On Error Resume Next
  94.         Dim i
  95.         For i = 0 To UBound(rvarMachine)
  96.             If rvarMachine(i) = "" Then
  97.                 Exit For
  98.             End If
  100.             Dim objWMIService
  101.             Set objWMIService = GetObject("winmgmts:\\" & rvarMachine(i) & "\root\cimv2:Win32_Process")
  102.             Dim intProcessID
  104. 'TODO：管理者ユーザーIDと管理者ユーザーパスワードの指定
  105.             Call objWMIService.Create("net use \\" & SERVER_NAME & "\C$ /user:" & SERVER_NAME & "\[管理者ログインID] [管理者ログインパスワード]", Null, Null, intProcessID)
  107.             '※音がなったりならなかったりと不安定のため
  108.             WScript.Sleep 3000
  110.             Call objWMIService.Create("\\" & SERVER_NAME & SHARED_PATH & "excsnd.exe", Null, Null, intProcessID)
  112.             '※音がなったりならなかったりと不安定のため
  113.             WScript.Sleep 3000
  115.             Call objWMIService.Create("net use \\" & SERVER_NAME & "\C$ /delete", Null, Null, intProcessID)
  117.             Set objWMIService = Nothing
  119.             If (Err.Number <> 0) Then
  120.                 Message = CStr(Err.Number) & ":" & Err.Desciption
  121.                 Exit Function
  122.             End If
  123.         Next
  125.         On Error GoTo 0
  127.         PlaySoundPersonal = True
  128.     End Function
  129. End Class

Facade.vbs

  1. '※このプログラムを実行するには、管理者権限が必要です
  2. Option Explicit
  4. Dim fso
  5. Set fso = CreateObject("Scripting.FileSystemObject")
  6. Function Include(ByVal fileName)
  7.     Include = fso.OpenTextFile(fileName, 1, False).ReadAll()
  8. End Function
  9. Execute Include(".\ExcSnd.vbs")
  10. Execute Include("..\..\common\FileCommon.vbs")
  11. Execute Include("..\..\common\TextFileManager.vbs")
  12. Execute Include("..\..\common\LogFile.vbs")
  14. '********************************************************************************
  15. ' 関数名：Main
  16. ' 概要　：警告音再生
  17. ' 引数　：なし
  18. ' 戻り値：なし
  19. '********************************************************************************
  20. Sub Main()
  21.     Dim startTime
  22.     startTime = Now()
  24.     Dim es
  25.     Set es = New ExcSnd
  27.     Dim bRet
  28.     bRet = es.PlaySound()
  29.     If (bRet = False) Then
  30.         Call WriteLog(startTime, es.Message)
  31.     End If
  33.     Set es = Nothing
  34. End Sub
  36. '********************************************************************************
  37. ' 関数名：WriteLog
  38. ' 概要　：エラーログを出力する
  39. ' 引数　：[startTime] - 実行開始
  40. ' 　　　　[msg] - メインクラスからのメッセージ
  41. ' 戻り値：なし
  42. '********************************************************************************
  43. Sub WriteLog(ByVal startTime, ByVal msg)
  44.     Const LOGFILE_PATH = "L:\警告音再生エラーログ.log"
  46.     Dim fc
  47.     Set fc = New FileCommon
  48.     Call fc.FileDelete(LOGFILE_PATH)
  49.     Set fc = Nothing
  51.     Dim oLog
  52.     Set oLog = New LogFile
  53.     oLog.FileName = LOGFILE_PATH
  55.     Dim sLog
  56.     sLog = ""
  57.     sLog = sLog & "実行開始時間：" & CStr(startTime) & vbCrLf
  58.     sLog = sLog & "実行終了時間：" & CStr(Now()) & vbCrLf
  59.     sLog = sLog & vbCrLf
  60.     sLog = sLog & "警告音再生に失敗しました。" & vbCrLf
  61.     sLog = sLog & "エラーの詳細は、以下のとおりです。" & vbCrLf
  62.     sLog = sLog & vbCrLf
  63.     sLog = sLog & msg & vbCrLf
  65.     oLog.AddText sLog
  67.     Set oLog = Nothing
  68. End Sub
投稿者 時刻:
ラベル: ,

0 件のコメント:

コメントを投稿

登録: コメントの投稿 (Atom)